"The door is locked, Nigel Paravane, you can't come in."

This function stops being useful when the avatar leaves the sim or is not in the same region as the object with which it is interacting. It may work for a little while after the avatar leaves the sim, but don't count on it. In a moment we'll see where a key comes from in the first place. Keys make it easy to compare whether two avatars are the same.

If you look at the picture on the right, there are two avatars and one group, and hence three keys associated with the door. The first is the "creator" of the door, and it is me. I haven't given or sold the door to anyone, so I am also the "owner" of the door. As the owner, I can set the "group" for the door to be any group to which I belong. For this object I set it to "NP Complete Design and Construction," which shows up in abbreviated form.

Right here we have three possibilities for giving permission to operate our door. We could open or close it only for the creator, the owner, or anyone who is in the group to which the door is set. We could also give permission to some combination of these.

Regarding the group option, suppose that you had a part of your building that was limited so that only certain people could get into it. These might be research scientists, financial managers, or VIPs for a nightclub. All these people could become members of a group and then have the door set to open only for people in that group. That way only they would be able to go in or out.

Actually, that's a bit simplistic because someone might tailgate behind an avatar who was authorized. That is, they might quickly follow an approved person through an open door. There are more extreme security measures to make sure that does not happen or else eject them if it does, but that is beyond the scope of this section.

To begin our coding, we'll modify the second script in the section on phantom doors so that the door will only open for the owner. We'll let anyone close it, to keep things simple. The basic idea is that when the door is closed and someone clicks on it, we get the identifying key of the avatar and then compare that with the identifying key of the door owner. If they are equal, we move the door into the open state. If not, we display a message and leave the door locked.

The original code was quite simple:

    // What we do when the door is clicked ("touched") with the mouse

    touch_start(integer total_number) {
        state open;                         // Move to the open state
    }

What is the integer parameter called total_number that is being passed to touch_start  that we are evidently not using? Imagine that you and a friend are standing in front of the door and you both click it at the same time. The value of total_number would be 2 since the two of you simultaneously touched the door. Most of the time total_number will just be 1.

    // What we do when the door is clicked ("touched") with the mouse

    touch_start(integer total_number) {
        // If the door was clicked by the owner of the door, open it,
        // otherwise give a message.
        
        if (llGetOwner() == llDetectedKey(0)) {
            state open;                         // Move to the open state
        }
        else {
            llSay(0, "Sorry, "+llDetectedName(0)+", this door can only be opened by the owner.");
        }
    }

    // What we do when the door is clicked ("touched") with the mouse

    touch_start(integer total_number) {
        // If the door was clicked by the owner of the door, open it,
        // otherwise give a message. Check everyone who clicked the door.
        
        integer allow_access = FALSE;
        integer i;

        for (i = 0; i < total_number && ! allow_access; ++i) {
            if (llGetOwner() == llDetectedKey(i)) {
                allow_access = TRUE;
            }
        }
        
        if (allow_access) {
            state open;                         // Move to the open state
        }
        else {
            llSay(0, "Sorry, you are not authorized to open the door.");
        }
    }